persönliches was sonst nirgens festgehalten würde.

Donnerstag, Oktober 07, 2004

OS aus Batch differenzieren

Wie vorher schon besprochen gab es einige Probleme mit dem Aufrufen von PDF Dateien. Abgesehen von den Tippfehlern hatte die Methode einen erheblichen Nachteil:
Unter win NT/2000/XP wurde u.U. nach einem passenden Programm gefragt, wenn kein Acrobat installiert war. Das ist natürlich nicht so toll, denn der unerfahrene User wird da mit Dingen konfrontiert die ihn im Moment nicht interessieren. Er will ja nur ein Dokument lesen.

Daher stöberte ich noch etwas und stieß auf folgendes:
In der Systemvariable COMSPEC steht was für eine Shell man benutzt. Für Win 95/98 ist das COMMAND.EXE und für die 'höheren' Versionen ist es CMD.EXE. Ich kann jetzt also zwischen den Betriebssystemen unterscheiden und beide erwähnten Methoden anwenden. Das komplette Skript lautet jetzt:

@ECHO OFF


::Check for Parameter
IF [%1]==[] GOTO Syntax

:: Checking OS
if "%COMSPEC%"=="C:\WINNT\system32\cmd.exe" GOTO nt
if "%COMSPEC%"=="C:\WINDOWS\system32\cmd.exe" GOTO nt

:: Win98 Part
::Start pdf file to check if Reader is installed
START /max ../pdf/%1>NUL

::If first START was successfull exit
IF NOT ERRORLEVEL 1 GOTO end

::Start supplied Reader
START /wait AcroRd32.exe ../pdf/%1
GOTO end

::WinNT/2000/XP Part
:nt
SET ADOBE=
ASSOC .pdf
IF NOT ERRORLEVEL 1 SET ADOBE=AcroRd32.exe
START %ADOBE% ../pdf/%1
GOTO end

:Syntax
ECHO.
ECHO startpdf.bat, Version 0.9 for (hopefully) every starting from Windows 98
ECHO Run a pdf file with installed viewer or if none installed use a supplied one.
ECHO.
ECHO Usage: startpdf "filename"
ECHO.
ECHO Where: "filename" is name of the pdf to display WITHOUT the ".pdf" extension.
ECHO.

:end
EXIT
Lief auf allen Systemen mit und ohne installiertem Acrobat.

Kleiner Nachteil: Das Skript ist etwas unflexibel was unkonventionelle Installationen von Windows betrifft. Sollte NT/2000/XP nicht im Standartverzeichnis installiert sein, setzt die Win 95/98 Routine ein und fragt möglicherweise nach einem Programm zum starten von PDFs. Aber wer sein Windows nicht in das Standartverzeichnis installiert wird schon wissen mit was er seine PDFs betrachten möchte...

Ich hoffe nur, dass ich nicht nochmal dran schrauben muss...

1 Kommentar:

Anonym hat gesagt…

Wir haben es so gelöst:

@echo off
if "%OS%"=="Windows_NT" GOTO NT
if "%OS%"=="WINNT" GOTO NT
goto W95
:NT
%windir%\system32\Regsvr32.exe /s %windir%\system32\zinsmodule.dll
%windir%\system32\Regsvr32.exe /s %windir%\system32\Comctl32.ocx
%windir%\system32\Regsvr32.exe /s %windir%\system32\ComdlgK2.ocx
%windir%\system32\Regsvr32.exe /s %windir%\system32\Mscomctl.ocx
%windir%\system32\Regsvr32.exe /s %windir%\system32\dao360.dll
%windir%\system32\Regsvr32.exe /s %windir%\system32\MSVBVM60.DLL
%windir%\system32\Regsvr32.exe /s %windir%\system32\msado15.dll
goto ende
:W95
%windir%\system\Regsvr32.exe /s %windir%\system\zinsmodule.dll
%windir%\system\Regsvr32.exe /s %windir%\system\Comctl32.ocx
%windir%\system\Regsvr32.exe /s %windir%\system\ComdlgK2.ocx
%windir%\system\Regsvr32.exe /s %windir%\system\Mscomctl.ocx
%windir%\system\Regsvr32.exe /s %windir%\system\dao360.dll
%windir%\system\Regsvr32.exe /s %windir%\system\MSVBVM60.DLL
%windir%\system\Regsvr32.exe /s %windir%\system\msado15.dll
:ende
@echo on